/*****************
 * VARIÁVEIS
 * crios todas variaveis aqui
 ****************/
 
var arquivoExternoUrl:URLRequest; //endereço do arquivo externo
var carregador:Loader; //recebe conteudo do arquivoURL
var arquivoExternoMc:MovieClip; //vai receber o conteudo do Carregador(Loader)
var ligaDesliga:Boolean; //responsavel por ligar e desligar animação
 
//começa tudo aqui
iniciaPrograma();
 
 
/*****************
 * FUNÇÕES
 * crios todas funções aqui separada pra cada tarefa
 ****************/
 
//inicia instancias das variaveis e cadastra valores
function iniciaPrograma():void
{
	ligaDesliga = false; //variavel começa desligada
	arquivoExternoUrl = new URLRequest("arquivo_externo.swf"); //inicia endereço do arquivo externo
	carregador = new Loader(); //inicia loader
	carregador.load(arquivoExternoUrl); //carregado arquivo externo
	carregador.contentLoaderInfo.addEventListener(Event.INIT, quandoIniciadoNoStage); //cadastra evento
	addChild(carregador); //deixa o loader visivel no stage
}
 
 
/*função de evento Event.INIT, 
faz alguma coisa quando o arquivo for carregado e iniciado no stage,
isso garante evitar erros de acesso ao arquivo externo
antes que ele seja carregado por completo*/
function quandoIniciadoNoStage(e:Event):void
{
	trace("* Carregou o arquivo externo, faz algo com ele!");
	cadastraConteudoNoMovieClip();
}
 
/*função de evento MouseEvent.CLICK,
que comunica com arquivo externo carregado*/
function quandoClicarArquivoExternoMc(e:MouseEvent):void
{
	ligaDesligaAnimacao();
}
 
/*Cadasrto e converto o conteudo do Loader em uma variavel MovieClip
e manipulo arquivo externo como se fosse um MovieClip comum no stage*/
function cadastraConteudoNoMovieClip():void
{
	/*falo que o conteudo do Loader deve agir como MoveiClip
	também poderia usar o método contrutor MovieClip(carregador.content);*/
	arquivoExternoMc = carregador.content as MovieClip;
	arquivoExternoMc.stop(); //para animação pra não começar quando carregado
	arquivoExternoMc.buttonMode = true; //aplico para parecer "mãozinha" de clique
	arquivoExternoMc.addEventListener(MouseEvent.CLICK, quandoClicarArquivoExternoMc); //aplico evento de clique
}
 
 
//liga e desliga animação
function ligaDesligaAnimacao():void
{
	//inverto valores de liga(true) e desliga(false) cada vez que aciona ligaDesligaAnimacao()
	ligaDesliga = !ligaDesliga;
 
	/*verifica se esta variavel ligaDesligaAnimacao
	está ligada(true) ou desligada(false)*/
	if(ligaDesliga)
	{
		trace("* Clicou no arquivo externo, play timeline desse arquivo");
		arquivoExternoMc.play();
	}
	else
	{
		trace("* Clicou no arquivo externo, stop timeline desse arquivo");
		arquivoExternoMc.stop();
	}
}